PViewport Modelspace Coordinates

Is there a way to get the modelspace coordinates of the region displayed within a viewport? Now that everyone has fully embraced the multiple layout functionality from 2000, I would like to be able to output all of the viewport extents from all of the layout tabs of a drawing as polyline rectangles in modelspace.

With TwistAngle, Height, Width, and Scale properties, I can get the size and orientation of the box, but how do I figure out where to put it? The only coordinate properties I can find all relate to Paperspace.

Any help on this would be much appreciated!

 

Kevin

try something like this:

Function DrawVportFrame(VptObj As AcadPViewport)

Dim PliObj As AcadLWPolyline
Dim LlfPnt As Variant
Dim UrgPnt As Variant
Dim VptCen As Variant
Dim VptLlf(0 To 2) As Double
Dim VptUrg(0 To 2) As Double
Dim VtxLst(0 To 7) As Double
Dim XofSet As Double
Dim YofSet As Double

With VptObj
VptCen = .Center
XofSet = .Width / 2
YofSet = .Height / 2
VptLlf(0) = CDbl(VptCen(0)) - XofSet
VptLlf(1) = CDbl(VptCen(1)) - YofSet
VptLlf(2) = 0#
VptUrg(0) = CDbl(VptCen(0)) + XofSet
VptUrg(1) = CDbl(VptCen(1)) + YofSet
VptUrg(2) = 0#
LlfPnt = CVar(VptLlf)
UrgPnt = CVar(VptUrg)
With ThisDrawing
With .Utility
LlfPnt = .TranslateCoordinates(LlfPnt, acPaperSpaceDCS, acDisplayDCS,
False)
UrgPnt = .TranslateCoordinates(UrgPnt, acPaperSpaceDCS, acDisplayDCS,
False)
End With
VtxLst(0) = CDbl(LlfPnt(0)): VtxLst(1) = CDbl(LlfPnt(1))
VtxLst(2) = CDbl(UrgPnt(0)): VtxLst(3) = CDbl(LlfPnt(1))
VtxLst(4) = CDbl(UrgPnt(0)): VtxLst(5) = CDbl(UrgPnt(1))
VtxLst(6) = CDbl(LlfPnt(0)): VtxLst(7) = CDbl(UrgPnt(1))
Set PliObj = .ModelSpace.AddLightWeightPolyline(VtxLst)
End With
With PliObj
.Closed = True
.Color = acRed
.Update
End With
End With
End Function

Cheers

 

Jeff, Jurg,

Thanks! I knew there had to be a way. TranslateCoordinates does exactly what I need

Kevin